Освещение в курятнике

вот код, который корректно обрабатывает проблемную ситуацию, описанную в #47.
P.S. код менять полностью, весь скетч!

Код (C++):

#include <Wire.h>                                   //Подключаем библиотеку для использования I2C интерфейса с модулем RTC
#include <RTClib.h>
RTC_DS3231 rtc;

#define ON                    LOW         // метка для включения реле (поставить 1, если реле управляется высоким уровнем)
#define OFF                   HIGH        // метка для отключения реле (поставить 0, если реле управляется высоким уровнем)
#define EVENTS                4           // количество событий в сутки

const byte Relay1 = 11;                   // Используем цифровой ПОРТ 6 для ПЕРВОГО канала релейного модуля
const byte Relay2 = 12;                   // Используем цифровой ПОРТ 7 для ВТОРОГО канала релейного модуля
enum {LIGHT_OFF, LIGHT_ON, LIGHT_MIDDLE}; // перечисляем возможные события (состояния системы)

// Само расписание (каждая строка состоит из 3-х элементов: час, минута, событие)
byte shedule[EVENTS][3] = {
  7,  0,  LIGHT_MIDDLE,                   // в 7:00 включаем неяркую подсветку
  9,  30, LIGHT_ON,                       // в 9:30 включаем подсветку на полную (тусклая отключается автоматом, поэтому нефиг засорять расписание)
  12, 50, LIGHT_MIDDLE,                   // в 19:45 включаем неяркую подсветку (яркая отключается автоматом, поэтому нефиг засорять расписание)
  21, 15, LIGHT_OFF,                      // в 21:15 наступает полная темнота
};
unsigned int eventTime[EVENTS];           // массив для хранения хеша времени наступления события

void setup() {
  Wire.begin();
  Serial.begin(9600);
  pinMode(Relay1, OUTPUT);                 //Инициализируем порт для ПЕРВОГО канала как ВЫХОД
  pinMode(Relay2, OUTPUT);                 //Инициализируем порт для ВТОРОГО канала как ВЫХОД
  digitalWrite(Relay1, HIGH);              //Устанавливаем на входах релейного модуля ВЫСОКИЙ уровень
  digitalWrite(Relay2, HIGH);              //Т.к. используемый релейный модуль с опторазвязкой - управляется инверсной логикой
  for (byte event = 0; event < EVENTS; event++)
    eventTime[event] = 60 * shedule[event][0] + shedule[event][1];  // рассчитываем хеши времени наступления событий
}

// входной параметр - событие (одно из LIGHT_OFF, LIGHT_ON, LIGHT_MIDDLE)
void relayManager(byte state)
{
  Serial.println(state);
  switch (state)
  {
      Serial.println(state);
    case LIGHT_OFF:
      Serial.println("LIGHT_OFF");
      digitalWrite(Relay1, OFF);
      digitalWrite(Relay2, OFF);
      break;

    case LIGHT_ON:
      Serial.println("LIGHT_ON");
      digitalWrite(Relay1, ON);
      digitalWrite(Relay2, ON);
      break;

    case LIGHT_MIDDLE:
      Serial.println("LIGHT_MIDDLE");
      digitalWrite(Relay1, ON);
      digitalWrite(Relay2, OFF);
      break;
  } // конец switch
}


void loop()
{
  DateTime now = rtc.now();
  unsigned int currentTime = now.hour() * 60 + now.minute(); // рассчитываем хеш текущего времени (уникальный для каждой минуты в сутках)

  // ============== вывод данных в консоль
  char buffer[80];
  sprintf(buffer, "\n%d:%02d \t\t\t(currentTime = %d)", now.hour(), now.minute(), currentTime );
  Serial.println(buffer);
  for (byte event = 0; event < EVENTS; event++)
  {
    sprintf(buffer, "Shedule%d = %d:%02d \t(eventTime%d = %d)", event, shedule[event][0], shedule[event][1], event, eventTime[event] );
    Serial.println(buffer);
  }
  // ============================

  byte counter = 0;
  for (byte event = 0; event < EVENTS; event++) if (currentTime >= eventTime[event]) counter++;
  if (counter == 0) relayManager(LIGHT_OFF);
  else relayManager(shedule[counter - 1][2]);
  delay (5000); // временно для отладки, чтобы не мелькало на экране
}

 

Ну да. Это я на светиках тренировался

 

С этим поосторожнее, там видимый спектр отличается от привычного курам (особенно много синего в лентах "холодного свечения", которых на фото большинство).


Птицы гораздо более восприимчивы к красному и синему излучению, чем человек. Разные части спектра оказывают влияние на разные процессы в организме птицы. Неслучайно для кур-несушек предпочтительнее освещение красным светом, для бройлеров – сине-зеленым.
К тому же, перейдя на ленты, вы почти полностью лишили кур ИК-излучения (это и безсквозняковый обогрев, и комфорт).

 

RGB точно не надо - будет еще хуже.