РЕШЕНО Ответ на get запрос esp32

Я делаю приложение которое посылает запросы на сервер, который работает с ESP32. Подключение по wifi типа точки доступа, я делаю GET запрос на IP, но не знаю как выдать ответ(данные с датчика).

На данный момент код вот такой, т.е. сейчас я просто вывожу json на страницу.
Как мне послать данные в ответ на GET запрос?

Код (C++):

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include "ArduinoJson.h"
#include <WiFiAP.h>
#define BMX055_DISABLE_BMM                                  // Не использовать магнитометр. Курс будет ориентирован на начальное положение модуля
#include <iarduino_Position_BMX055.h>                       // Подключаем библиотеку iarduino_Position_BMX055 для работы с Trema-модулем IMU 9 DOF.
iarduino_Position_BMX055 sensor(BMX);
#define LED_BUILTIN 2   // Set the GPIO pin where you connected your test LED or comment this line out if your dev board has a built-in LED
// Set these to your desired credentials.
const char *ssid = "yourAP";
const char *password = "yourPassword";
WiFiServer server(80);
void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  Serial.begin(115200);
  sensor.begin();
  Serial.println();
  Serial.println("Configuring access point...");
  // You can remove the password parameter if you want the AP to be open.
  WiFi.softAP(ssid, password);
  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);
  server.begin();
  Serial.println("Server started");
}
String getQuat(){
  sensor.read();
  String res = String(sensor.q1) + String(sensor.q2) + String(sensor.q3) + String(sensor.q4);
  return res;
}
void loop() {
  DynamicJsonDocument doc(1024);
  WiFiClient client = server.available();   // listen for incoming clients
  if (client) {                             // if you get a client,
    Serial.println("New Client.");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();
            // the content of the HTTP response follows the header:
            client.print("Click <a href=\"/H\">here</a> to turn ON the LED.<br>");
            client.print("Click <a href=\"/L\">here</a> to turn OFF the LED.<br>");
            // The HTTP response ends with another blank line:
            //client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
        // Check to see if the client request was "GET /H" or "GET /L":
        doc["qX"] = sensor.q1;
        doc["qY"] = sensor.q2;
        doc["qZ"] = sensor.q3;
        doc["qW"] = sensor.q4;
        String outStr;
        serializeJson(doc, outStr);
        client.println(outStr);
        if (currentLine.endsWith("GET /H")) {
          digitalWrite(LED_BUILTIN, HIGH);               // GET /H turns the LED on
        }
        if (currentLine.endsWith("GET /L")) {
          digitalWrite(LED_BUILTIN, LOW);                // GET /L turns the LED off
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("Client Disconnected.");
  }
}

 

Решение, если вдруг кто столкнется с такой же проблемой:

Код (C++):

 
#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include "ESPAsyncWebServer.h"
#include "ArduinoJson.h"
#include <WiFiAP.h>
#define BMX055_DISABLE_BMM                                  // Не использовать магнитометр. Курс будет ориентирован на начальное положение модуля
#include <iarduino_Position_BMX055.h>                       // Подключаем библиотеку iarduino_Position_BMX055 для работы с Trema-модулем IMU 9 DOF.
iarduino_Position_BMX055 sensor(BMX);

#define LED_BUILTIN 2   // Set the GPIO pin where you connected your test LED or comment this line out if your dev board has a built-in LED

// Set these to your desired credentials.
const char *ssid = "yourAP";
const char *password = "yourPassword";

AsyncWebServer server(80);

DynamicJsonDocument doc(1024);

String getQuat(){
  sensor.read();
  String res = String(sensor.q1) + String(sensor.q2) + String(sensor.q3) + String(sensor.q4);
        doc["qX"] = sensor.q1;
        doc["qY"] = sensor.q2;
        doc["qZ"] = sensor.q3;
        doc["qW"] = sensor.q4;
        String outStr;
        serializeJson(doc, outStr);
  return outStr;
}

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);

  Serial.begin(115200);
  sensor.begin();
  Serial.println();
  Serial.println("Configuring access point...");

  // You can remove the password parameter if you want the AP to be open.
  WiFi.softAP(ssid, password);
  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);
  server.begin();
  server.on("/q", HTTP_GET, [](AsyncWebServerRequest *request){
      request->send_P(200, "application/json", getQuat().c_str());
        });
}

void loop() {
  //nichego...
}